Fprogram (P0):
 IF                   FI             'Els lefuts
 THEN  RESET          O0.1           'Lift fel
       SET            O0.0           'Lift le
       RESET          O0.2           'Kitols
       RESET          O0.3           'Leveg csszka
       RESET          F0.0           'Startflag

 IF            N      I0.7           'Kvi lloms szabad
 THEN  SET            O0.7           'lloms fogadkpes

 IF                   I0.7           'Kvi lloms szabad
       AND     N      F1.1           'Tlmretezett munkadarab
 THEN  RESET          O0.7           'lloms fogadkpes

 IF                   I1.0           'Start gomb
 THEN  SET            F0.0           'Startflag

 IF                   I1.1           'Stop gomb
 THEN  RESET          F0.0           'Startflag

 IF                   I1.2           'Reset gomb
       AND     N      F0.0           'Startflag
 THEN  RESET          O0.1           'Lift fel
       SET            O0.0           'Lift le
       RESET          O0.2           'Kitols
       RESET          O0.3           'Leveg csszka
       RESET          F0.0           'Startflag

 IF            N      I1.3           'Vszlellt gomb
 THEN  RESET          O0.3           'Leveg csszka
       RESET          F0.0           'Startflag
       RESET          P1             '1-es munkaprogram

 IF            N      P1             '1-es munkaprogram
       AND            F0.0           'Startflag
 THEN  SET            P1             '1-es munkaprogram

Munkaprogram (P1):
STEP 0
 IF                   F0.0           'Startflag
       AND            I0.0           'Munkadarab elrhet
       AND            I0.5           'Lift lent
       AND            I0.6           'Kitol visszahzva
       AND     N      I0.2           'Biztonsgi fnysoromp
 THEN  SET            T0             'Ksleltets
         WITH         0.5s
       JMP TO 1
 OTHRW JMP TO 0
 
STEP 1
 IF            N      T0             'Ksleltets
       AND     N      I0.0           'Munkadarab elrhet
 THEN  JMP TO 0

 IF            N      T0             'Ksleltets
       AND            I0.0           'Munkadarab elrhet
 THEN  SET            O0.1           'Lift fel
       RESET          O0.0           'Lift le

STEP 2
 IF                   I0.4           'Lift fent
 THEN  SET            T0             'Ksleltets
         WITH         0.2s

STEP 3
 IF            N      T0             'Ksleltets
 THEN                 NOP

STEP 4
 IF                   I0.3           'Munkadarab magassg megfelel
 THEN  SET            O0.2           'Kitols
       SET            T0             'Ksleltets
         WITH         0.6s
 OTHRW JMP TO 8

""Ha megfelel magassg a munkadarab
STEP 5
 IF            N      T0             'Ksleltets
 THEN  RESET          O0.2           'Kitols

STEP 6
 IF                   I0.6           'Kitol visszahzva
 THEN  SET            O0.3           'Leveg csszka
       RESET          O0.1           'Lift fel
       SET            O0.0           'Lift le
       SET            T0             'Ksleltets
         WITH         0.5s

STEP 7
 IF                   I0.5           'Lift lent
       AND     N      T0             'Ksleltets
 THEN  RESET          O0.3           'Leveg csszka
       JMP TO 0

""Ha nem megfelel magassg a munkadarab
STEP 8
 THEN  SET            F1.1           'Tlmretezett munkadarab
       RESET          O0.1           'Lift fel
       SET            O0.0           'Lift le

STEP 9
 IF                   I0.5           'Lift lent
 THEN  SET            O0.2           'Kitols
       SET            T0             'Ksleltets
         WITH         0.7s
 
STEP 10
 IF            N      T0             'Ksleltets
 THEN  RESET          O0.2           'Kitols
STEP 11
 IF                   I0.6           'Kitol visszahzva
 THEN  SET            O0.7           'lloms fogadkpes
       SET            T0             'Ksleltets
         WITH         0.3s
STEP 12
 IF            N      T0             'Ksleltets
 THEN  RESET          O0.7           'lloms fogadkpes
       RESET          F1.1           'Tlmretezett munkadarab
       JMP TO 0
