Fprogram (P0):
IF                   FI             'Els lefuts
 THEN  RESET          O0.0           'Futszalag indts
       RESET          O0.1           '1. terelgt 
       RESET          O0.2           '2. terelgt
       RESET          O0.3           'Vizsgl gt (alaphelyzetben kint)
       RESET          O0.7           'lloms nem fogadkpes
       RESET          F1.1           'Trolcsszka megtelt
       RESET          F0.0           'Startflag

 IF            N      P1             '1-es munkaprogram
       AND            F1.1           'Trolcsszka megtelt
 THEN  SET            O0.7           'lloms nem fogadkpes

 IF            N      I0.3           'Trolcsszka tele
       AND            F1.1           'Trolcsszka megtelt
 THEN  RESET          F1.1           'Trolcsszka megtelt
       RESET          O0.7           'lloms nem fogadkpes

 IF                   I1.0           'Start gomb
 THEN  SET            F0.0           'Startflag

 IF                   I1.1           'Stop gomb
 THEN  RESET          F0.0           'Startflag

 IF                   I1.2           'Reset gomb
       AND     N      F0.0           'Startflag
 THEN  RESET          O0.0           'Futszalag indts
       RESET          O0.1           '1. terelgt 
       RESET          O0.2           '2. terelgt
       RESET          O0.3           'Vizsgl gt (alaphelyzetben kint)
       RESET          O0.7           'lloms nem fogadkpes
       RESET          F0.0           'Startflag

 IF            N      I1.3           'Vszlellt gomb
 THEN  RESET          F0.0           'Startflag
       RESET          O0.0           'Futszalag indts
       RESET          O0.1           '1. terelgt 
       RESET          O0.2           '2. terelgt
       RESET          O0.3           'Vizsgl gt (alaphelyzetben kint)
       RESET          O0.7           'lloms nem fogadkpes
       RESET          P1             '1-es munkaprogram

 IF            N      P1             '1-es munkaprogram
       AND     N      F1.1           'Trolcsszka megtelt
       AND            F0.0           'Startflag
 THEN  SET            P1             '1-es munkaprogram
 
Munkaprogram (P1):
STEP 0
 THEN  RESET          O0.7           'lloms nem fogadkpes
       RESET          O0.1           '1. terelgt 
       RESET          O0.2           '2. terelgt
       RESET          O0.3           'Vizsgl gt (alaphelyzetben kint)

 IF                   I0.0           'Munkadarab elrhet
       AND            F0.0           'Startflag
 THEN  SET            T1             'Ksleltets
         WITH         1s
 OTHRW JMP TO 0

STEP 1
 IF            N      T1             'Ksleltets
 THEN  SET            O0.0           'Futszalag indts
       RESET          F0.1           'Piros munkadarab
       RESET          F0.2           'Fekete munkadarab
       RESET          F0.3           'Fm munkadarab
       SET            T1             'Ksleltets
         WITH         1s

STEP 2
 IF            N      T1             'Ksleltets
       AND     N      I0.0           'Munkadarab elrhet
       AND            I0.2           'Nem fekete munkadarab
       AND            I0.1           'Fm munkadarab
 THEN  SET            F0.3           'Fm munkadarab
       JMP TO 3
 IF            N      T1             'Ksleltets
       AND     N      I0.0           'Munkadarab elrhet
       AND     N      I0.2           'Nem fekete munkadarab
       AND     N      I0.1           'Fm munkadarab
 THEN  SET            F0.2           'Fekete munkadarab
       JMP TO 3

 IF            N      T1             'Ksleltets
       AND     N      I0.0           'Munkadarab elrhet
       AND     N      I0.1           'Fm munkadarab
       AND            I0.2           'Nem fekete munkadarab
 THEN  SET            F0.1           'Piros munkadarab
       JMP TO 3

STEP 3
 IF                   F0.1           'Piros munkadarab
 THEN  SET            O0.1           '1. terelgt 
       RESET          O0.2           '2. terelgt
       JMP TO 4
 IF                   F0.2           'Fekete munkadarab
 THEN  RESET          O0.1           '1. terelgt 
       SET            O0.2           '2. terelgt
       JMP TO 4
 IF                   F0.3           'Fm munkadarab
 THEN  RESET          O0.1           '1. terelgt 
       RESET          O0.2           '2. terelgt
       JMP TO 4
 
STEP 4
 IF              (    F0.3           'Fm munkadarab
       AND            I0.4           '1. terelgt alaphelyzetben
       AND            I0.6           '2. terelgt alaphelyzetben
                                )
       OR
                 (    F0.2           'Fekete munkadarab
       AND            I0.7           '2. terelgt kint
       AND            I0.4           '1. terelgt alaphelyzetben
                                )
       OR        (    F0.1           'Piros munkadarab
       AND            I0.5           '1. terelgt kint
       AND            I0.6           '2. terelgt alaphelyzetben
                                )
 THEN  SET            O0.3           'Vizsgl gt (alaphelyzetben kint)

STEP 5
 IF                   I0.3           'Trolcsszka tele
 THEN  RESET          O0.0           'Futszalag indts
       SET            T2             'Ksleltets
         WITH         0.5s

STEP 6
 IF            N      I0.3           'Trolcsszka tele
 THEN  RESET          O0.1           '1. terelgt 
       RESET          O0.2           '2. terelgt
       RESET          O0.3           'Vizsgl gt (alaphelyzetben kint)
       JMP TO 0
 IF                   I0.3           'Trolcsszka tele
       AND     N      T2             'Ksleltets
 THEN  SET            F1.1           'Trolcsszka megtelt
       RESET          P1             '1-es munkaprogram
